Merge remote-tracking branch 'gum/master'

makefu/1systems/x/config.nix

@@ -7,6 +7,10 @@
     [ # base
       <stockholm/makefu>
       <stockholm/makefu/2configs/nur.nix>
+      <stockholm/makefu/2configs/home-manager>
+      <stockholm/makefu/2configs/home-manager/desktop.nix>
+      <stockholm/makefu/2configs/home-manager/cli.nix>
+      <stockholm/makefu/2configs/home-manager/mail.nix>
       <stockholm/makefu/2configs/main-laptop.nix>
       <stockholm/makefu/2configs/extra-fonts.nix>
       <stockholm/makefu/2configs/tools/all.nix>

makefu/1systems/x/source.nix

@@ -6,5 +6,6 @@
   unstable = true;
   mic92 = true;
   clever_kexec = true;
+  home-manager = true;
   # torrent = true;
 }

makefu/2configs/home-manager/cli.nix

@@ -0,0 +1,12 @@
+{
+  home-manager.users.makefu = {
+    services.gpg-agent = {
+      defaultCacheTtl = 900;
+      maxCacheTtl = 7200;
+      defaultCacheTtlSsh = 3600;
+      maxCacheTtlSsh = 86400;
+      enableSshSupport = true;
+    };
+    programs.fzf.enable = true; # alt-c
+  };
+}

makefu/2configs/home-manager/default.nix

@@ -0,0 +1,7 @@
+{
+  imports = [
+    <home-manager/nixos>
+  ];
+  home-manager.users.makefu = {
+  };
+}

makefu/2configs/home-manager/desktop.nix

@@ -0,0 +1,31 @@
+{pkgs, ... }: {
+  home-manager.users.makefu = {
+    programs.browserpass = { browsers = [ "firefox" ] ; enable = true; };
+    services.network-manager-applet.enable = true;
+    services.blueman-applet.enable = true;
+    services.pasystray.enable = true;
+
+  systemd.user.services.network-manager-applet.Service.Environment = ''
+        XDG_DATA_DIRS=/etc/profiles/per-user/makefu/share GDK_PIXBUF_MODULE_FILE=${pkgs.librsvg.out}/lib/gdk-pixbuf-2.0/2.10.0/loaders.cache
+      '';
+  systemd.user.services.clipit = {
+    Unit = {
+      Description = "clipboard manager";
+      After = [ "graphical-session-pre.target" ];
+      PartOf = [ "graphical-session.target" ];
+    };
+
+    Install = {
+      WantedBy = [ "graphical-session.target" ];
+    };
+
+    Service = {
+      Environment = ''
+        XDG_DATA_DIRS=/etc/profiles/per-user/makefu/share GDK_PIXBUF_MODULE_FILE=${pkgs.librsvg.out}/lib/gdk-pixbuf-2.0/2.10.0/loaders.cache
+      '';
+      ExecStart = "${pkgs.clipit}/bin/clipit";
+      Restart = "on-abort";
+    };
+  };
+  };
+}

makefu/2configs/home-manager/mail.nix

@@ -0,0 +1,46 @@
+{
+  home-manager.users.makefu = {
+    accounts.email.accounts.syntaxfehler = {
+      address = "felix.richter@syntax-fehler.de";
+      userName = "Felix.Richter@syntax-fehler.de";
+      imap = {
+        host = "syntax-fehler.de";
+        tls = {
+          enable = true;
+        };
+      };
+      smtp = {
+        host = "syntax-fehler.de";
+        tls = {
+          enable = true;
+        };
+      };
+      msmtp.enable = true;
+      notmuch.enable = true;
+      offlineimap = {
+        enable = true;
+        postSyncHookCommand = "notmuch new";
+        extraConfig.remote = {
+          holdconnectionopen = true;
+          idlefolders = "['INBOX']";
+        };
+      };
+      primary = true;
+      realName = "Felix Richter";
+      passwordCommand = "gpg --use-agent --quiet --batch -d /home/makefu/.mail/syntax-fehler.gpg";
+    };
+    programs.offlineimap.enable = true;
+    programs.offlineimap.extraConfig = {
+      mbnames = {
+        filename = "~/.mutt/muttrc.mailboxes";
+        header = "'mailboxes '";
+        peritem = "'+%(accountname)s/%(foldername)s'";
+        sep = "' '";
+        footer = "'\\n'";
+      };
+      general = {
+        ui = "TTY.TTYUI";
+      };
+    };
+  };
+}

makefu/3modules/airdcpp.nix

@@ -0,0 +1,210 @@
+{ config, lib, pkgs, ... }:
+with import <stockholm/lib>; #genid
+let
+  cfg = config.makefu.airdcpp;
+
+  out = {
+    options.makefu.airdcpp = api;
+    config = lib.mkIf cfg.enable imp;
+  };
+
+  api = with types;{
+    enable = mkEnableOption "airdcpp";
+
+    package = mkOption {
+      type = package;
+      default = pkgs.airdcpp-webclient;
+    };
+
+    user = mkOption {
+      description = ''
+        user which will run udpt. if kept default a new user will be created
+      '';
+      type = str;
+      default = "airdcpp";
+    };
+    extraGroups = mkOption {
+      description = ''extra groups for the user (only for default user)'';
+      type = listOf str;
+      default = [];
+      example = [ "nginx" ];
+    };
+
+    stateDir = mkOption {
+      description = ''
+        directory for storing state (pid,config)
+      '';
+      type = str;
+      default = "/var/lib/airdcpp";
+    };
+    dcpp = {
+      Nick = mkOption {
+        description = ''
+          Nick Name for connection
+        '';
+        type = str;
+        default = "kevin";
+      };
+      InPort = mkOption {
+        description = "Input Port";
+        type = int;
+        default = 16849;
+      };
+      UDPPort = mkOption {
+        description = "UDP open Port";
+        type = int;
+        default = 16849;
+      };
+      TLSPort = mkOption {
+        description = "TLS open Port";
+        type = int;
+        default = 16869;
+      };
+      DownloadSpeed = mkOption {
+        description = "Total Download Speed in Mbps/s";
+        type = str;
+        default = "100";
+      };
+      UploadSpeed = mkOption {
+        description = "Total Upload Speed in Mbp/s";
+        type = str;
+        default = "100";
+      };
+      shares = mkOption {
+        default = {};
+        type = attrsOf (submodule ( { config, ... }: {
+          options = {
+            path = mkOption {
+              description = "path to the share";
+              type = str;
+            };
+            incoming = mkOption {
+              description = "incoming";
+              type = bool;
+              default = false;
+            };
+          };
+        }));
+      };
+      initialConfigFile = mkOption {
+        description = ''
+          path inital DCPlusPlus.xml configuration if none exists
+        '';
+        type = nullOr path;
+        default = null;
+      };
+    };
+    web = {
+      port = mkOption {
+        description = ''web-ui port
+
+        NOTE: once the initial config had been written to the state directory it will not be replaced
+        '';
+        type = int;
+        default = 5600;
+      };
+      initialConfigFile = mkOption {
+        description = ''
+          path inital WebServer.xml configuration if none exists
+        '';
+        type = nullOr path;
+        default = null;
+      };
+      # TODO: tlsPort
+      users = mkOption {
+        type = attrsOf (submodule ( { config, ... }: {
+          options = {
+            password = mkOption {
+              description = "password of user";
+              type = str;
+            };
+            permissions = mkOption {
+              description = "user permissions";
+              type = str;
+              default = "admin";
+            };
+          };
+        }));
+      };
+    };
+  };
+
+  imp = let
+    genUsers = users: concatMapStringsSep "\n" (user: 
+      ''<WebUser Username="${user.name}" Password="${user.password}" LastLogin="0" Permissions="${user.permissions}"/>'' )
+      (mapAttrsToList (name: val: val // { inherit name; }) users);
+    genShares = shares: concatMapStringsSep "\n" (share:
+      ''<Directory Virtual="stockholm" Incoming="${
+          if share.incoming then "1" else "0"
+        }" LastRefreshTime="0">${share.path}</Directory>'' )
+      (mapAttrsToList (name: val: val // { inherit name; }) shares);
+    webConfigFile = if (cfg.web.initialConfigFile == null) then builtins.trace "warning: airdcpp passwords are stored in plain text" pkgs.writeText "initial-config" ''
+      <?xml version="1.0" encoding="utf-8" standalone="yes"?>
+      <WebServer>
+        <Config>
+          <Server Port="${toString cfg.web.port}"/>
+          <TLSServer Port="0" Certificate="" CertificateKey=""/>
+        </Config>
+        <WebUsers>${genUsers cfg.web.users}
+        </WebUsers>
+      </WebServer>
+      '' else cfg.web.initialConfigFile;
+    dcppConfigFile = if (cfg.dcpp.initialConfigFile == null) then pkgs.writeText "initial-config" ''
+    <?xml version="1.0" encoding="utf-8" standalone="yes"?>
+    <DCPlusPlus>
+      <Settings>
+        <Nick type="string">${cfg.dcpp.Nick}</Nick>
+        <ConfigVersion type="string">${cfg.package.version}</ConfigVersion>
+        <InPort type="int">${toString cfg.dcpp.InPort}</InPort>
+        <UDPPort type="int">${toString cfg.dcpp.UDPPort}</UDPPort>
+        <TLSPort type="int">${toString cfg.dcpp.TLSPort}</TLSPort>
+        <ConfigBuildNumber type="int">0</ConfigBuildNumber>
+        <AutoDetectIncomingConnection type="int">0</AutoDetectIncomingConnection>
+        <NoIpOverride type="int">1</NoIpOverride>
+        <WizardRunNew type="int">0</WizardRunNew>
+        <IPUpdate type="int">0</IPUpdate>
+        <AlwaysCCPM type="int">1</AlwaysCCPM>
+        <DownloadSpeed type="string">${cfg.dcpp.DownloadSpeed}</DownloadSpeed>
+        <UploadSpeed type="string">${cfg.dcpp.UploadSpeed}</UploadSpeed>
+      </Settings>
+      <Share Token="0" Name="Default">
+        ${genShares cfg.dcpp.shares}
+        <NoShare/>
+      </Share>
+      <ChatFilterItems/>
+    </DCPlusPlus>
+    '' else cfg.dcpp.initialConfigFile;
+  in {
+    systemd.services.airdcpp = {
+      description = "airdcpp webui";
+      after = [ "network.target" ];
+      wantedBy = [ "multi-user.target" ];
+      restartIfChanged = true;
+      serviceConfig = {
+        Type = "simple";
+        ExecStartPre = pkgs.writeDash "prepare-env" ''
+          d=${cfg.stateDir}/WebServer.xml
+          test -e $d || install -m700 -o${cfg.user} ${webConfigFile} $d
+          d=${cfg.stateDir}/DCPlusPlus.xml
+          test -e $d || install -m700 -o${cfg.user} ${dcppConfigFile} $d
+        '';
+        PermissionsStartOnly = true;
+        ExecStart = "${cfg.package}/bin/airdcppd -c=${cfg.stateDir} -p=${cfg.stateDir}/airdcpp.pid";
+        PrivateTmp = true;
+        WorkingDirectory = cfg.stateDir;
+        User = "${cfg.user}";
+      };
+    };
+    users = lib.mkIf (cfg.user == "airdcpp") {
+      users.airdcpp = {
+        uid = genid "airdcpp";
+        home = cfg.stateDir;
+        createHome = true;
+        inherit (cfg) extraGroups;
+      };
+      groups.airdcpp.gid = genid "airdcpp";
+    };
+  };
+in
+out
+

makefu/5pkgs/airdcpp-webclient/default.nix

@@ -0,0 +1,27 @@
+{ stdenv, fetchurl
+}:
+stdenv.mkDerivation rec {
+  name = "airdcpp-webclient-${version}";
+  version = "2.3.0";
+  
+  src = fetchurl {
+    url = http://web-builds.airdcpp.net/stable/airdcpp_2.3.0_webui-2.3.0_64-bit_portable.tar.gz;
+    sha256 = "0yvcl0nc70fghc7vfsgvbpryi5q97arld8adql4way4qa0mdnyv1";
+  };
+
+  phases = [ "unpackPhase" "installPhase" ];
+  installPhase = ''
+    mkdir -p $out/{share,bin}
+    cp -r *  $out/share
+    ln -s $out/share/airdcppd $out/bin/
+  '';
+
+  meta = with stdenv.lib; {
+    # to start it: airdcpp -p=<pid-file> -c=<config-store-path (must be writeable)> --configure
+    description = "dcpp client (statically precompiled)";
+    homepage = http://fixme;
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ makefu ];
+    platforms = with platforms; linux;
+  };
+}

makefu/5pkgs/pavumeter/default.nix

@@ -0,0 +1,30 @@
+{ lib, stdenv,  fetchurl, libusb, libtool, autoconf, pkgconfig, git,
+gettext, automake, libxml2 
+, autoreconfHook
+, lynx
+, gtkmm2
+, libpulseaudio
+, gnome2
+, libsigcxx
+}:
+stdenv.mkDerivation rec {
+  pname = "pavumeter";
+  name = "${pname}-${version}";
+  version = "0.9.3";
+
+  src = fetchurl {
+    url = "http://0pointer.de/lennart/projects/${pname}/${name}.tar.gz";
+    sha256 = "0yq67w8j8l1xsv8pp37bylax22npd6msbavr6pb25yvyq825i3gx";
+  };
+
+  buildInputs = [ gtkmm2 libpulseaudio gnome2.gnome_icon_theme ];
+  nativeBuildInputs = [ pkgconfig autoreconfHook lynx ];
+
+  meta = {
+    description = "PulseAudio volumene meter";
+    homepage = http://0pointer.de/lennart/projects/pavumeter;
+    license = stdenv.lib.licenses.gpl2;
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ makefu ];
+  };
+}

makefu/krops.nix

@@ -20,12 +20,11 @@
     nms = false;
     arm6 = false;
     clever_kexec = false;
+    home-manager = false;
   } // import (./. + "/1systems/${name}/source.nix");
   source = { test }: lib.evalSource [
     {
-      # nixos-18.03 @ 2018-08-06
-      # + do_sqlite3 ruby:   55a952be5b5
-      # + exfat-nofuse bump: ee6a5296a35
+      # nixos-18.09 @ 2018-09-18
       # + uhub/sqlite: 5dd7610401747
       nixpkgs = if test || host-src.full then {
         git.ref = nixpkgs-src.rev;
@@ -70,6 +69,12 @@
         ref = "30fdd53";
       };
     })
+    (lib.mkIf ( host-src.home-manager ) {
+      home-manager.git = {
+        url = https://github.com/rycee/home-manager;
+        ref = "6eea2a4";
+      };
+    })
   ];
 
 in {