From d5db8b88edbf40df3b48364429310872edb64cea Mon Sep 17 00:00:00 2001
From: tv <tv@krebsco.de>
Date: Sun, 21 Feb 2016 06:23:06 +0100
Subject: tv.charybdis: use krebs.secret

---
 tv/3modules/charybdis/default.nix | 90 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 90 insertions(+)
 create mode 100644 tv/3modules/charybdis/default.nix

(limited to 'tv/3modules/charybdis/default.nix')

diff --git a/tv/3modules/charybdis/default.nix b/tv/3modules/charybdis/default.nix
new file mode 100644
index 000000000..0bab69529
--- /dev/null
+++ b/tv/3modules/charybdis/default.nix
@@ -0,0 +1,90 @@
+{ config, lib, pkgs, ... }@args: with config.krebs.lib; let
+  cfg = config.tv.charybdis;
+in {
+  options.tv.charybdis = {
+    enable = mkEnableOption "tv.charybdis";
+    motd = mkOption {
+      type = types.str;
+      default = "/join #retiolum";
+    };
+    port = mkOption {
+      type = types.int;
+      default = 6667;
+    };
+    ssl_cert = mkOption {
+      type = types.path;
+    };
+    ssl_dh_params = mkOption {
+      type = types.secret-file;
+      default = {
+        path = "${cfg.user.home}/dh.pem";
+        owner-name = "charybdis";
+        source-path = toString <secrets> + "/charybdis.dh.pem";
+      };
+    };
+    ssl_private_key = mkOption {
+      type = types.secret-file;
+      default = {
+        path = "${cfg.user.home}/ssl.key.pem";
+        owner-name = "charybdis";
+        source-path = toString <secrets> + "/charybdis.key.pem";
+      };
+    };
+    sslport = mkOption {
+      type = types.int;
+      default = 6697;
+    };
+    user = mkOption {
+      type = types.submodule {
+        options = {
+          name = mkOption {
+            type = types.str;
+          };
+          home = mkOption {
+            type = types.str;
+          };
+        };
+      };
+      default = {
+        name = "charybdis";
+        home = "/var/lib/charybdis";
+      };
+    };
+  };
+  config = lib.mkIf cfg.enable {
+
+    krebs.secret.files.charybdis-ssl_dh_params = cfg.ssl_dh_params;
+    krebs.secret.files.charybdis-ssl_private_key = cfg.ssl_private_key;
+
+    environment.etc."charybdis-ircd.motd".text = cfg.motd;
+
+    systemd.services.charybdis = {
+      wantedBy = [ "multi-user.target" ];
+      requires = [ "secret.service" ];
+      after = [ "network.target" "secret.service" ];
+      environment = {
+        BANDB_DBPATH = "${cfg.user.home}/ban.db";
+      };
+      serviceConfig = {
+        SyslogIdentifier = "charybdis";
+        User = cfg.user.name;
+        PrivateTmp = true;
+        Restart = "always";
+        ExecStartPre =
+          "${pkgs.coreutils}/bin/ln -s /etc/charybdis-ircd.motd /tmp/ircd.motd";
+        ExecStart = toString [
+          "${pkgs.charybdis}/bin/charybdis-ircd"
+            "-configfile ${import ./config.nix args}"
+            "-foreground"
+            "-logfile /dev/stderr"
+        ];
+      };
+    };
+
+    users.users.${cfg.user.name} = {
+      inherit (cfg.user) home name;
+      createHome = true;
+      uid = genid cfg.user.name;
+    };
+  };
+}
-- 
cgit v1.2.3

[cgit] Unable to lock slot /tmp/cgit/60300000.lock: No such file or directory (2)