4 files changed, 75 insertions, 2 deletions
diff --git a/krebs/4lib/default.nix b/krebs/4lib/default.nix
index b67585335..ca7219c7e 100644
--- a/krebs/4lib/default.nix
+++ b/krebs/4lib/default.nix
@@ -14,5 +14,12 @@ builtins // lib // rec {
 
   dns = import ./dns.nix { inherit lib; };
   listset = import ./listset.nix { inherit lib; };
+  shell = import ./shell.nix { inherit lib; };
   tree = import ./tree.nix { inherit lib; };
+
+  toC = x: {
+    list = "{ ${concatStringsSep ", " (map toC x)} }";
+    null = "NULL";
+    string = toJSON x; # close enough
+  }.${typeOf x};
 }
diff --git a/krebs/4lib/shell.nix b/krebs/4lib/shell.nix
new file mode 100644
index 000000000..2a6da5c16
--- /dev/null
+++ b/krebs/4lib/shell.nix
@@ -0,0 +1,22 @@
+{ lib, ... }:
+
+with builtins;
+with lib;
+
+rec {
+  escape =
+    let
+      isSafeChar = c: match "[-./0-9_a-zA-Z]" c != null;
+    in
+    stringAsChars (c:
+      if isSafeChar c then c
+      else if c == "\n" then "'\n'"
+      else "\\${c}");
+
+  #
+  # shell script generators
+  #
+
+  # example: "${cat (toJSON { foo = "bar"; })} | jq -r .foo"
+  cat = s: "printf '%s' ${escape s}";
+}
diff --git a/krebs/5pkgs/default.nix b/krebs/5pkgs/default.nix
index 062f0a515..3658c43e0 100644
--- a/krebs/5pkgs/default.nix
+++ b/krebs/5pkgs/default.nix
@@ -1,17 +1,45 @@
-{ pkgs, ... }:
+{ lib, pkgs, ... }:
+
+with import ../4lib { inherit lib; };
 
 let
   inherit (pkgs) callPackage;
 in
 
 pkgs //
-{
+rec {
   cac = callPackage ./cac.nix {};
   dic = callPackage ./dic.nix {};
   genid = callPackage ./genid.nix {};
   github-hosts-sync = callPackage ./github-hosts-sync.nix {};
   github-known_hosts = callPackage ./github-known_hosts.nix {};
   hashPassword = callPackage ./hashPassword.nix {};
+  nq = callPackage ./nq.nix {};
   posix-array = callPackage ./posix-array.nix {};
   youtube-tools = callPackage ./youtube-tools.nix {};
+
+  execve = name: { filename, argv, envp }:
+    writeC name {} ''
+      #include <unistd.h>
+      int main () {
+        const char *filename = ${toC filename};
+        char *const argv[] = ${toC (argv ++ [null])};
+        char *const envp[] = ${toC (
+          mapAttrsToList (k: v: "${k}=${v}") envp ++ [null]
+        )};
+        execve(filename, argv, envp);
+        return -1;
+      }
+    '';
+
+  writeC = name: {}: src: pkgs.runCommand name {} ''
+    PATH=${lib.makeSearchPath "bin" (with pkgs; [
+      binutils
+      coreutils
+      gcc
+    ])}
+    in=${pkgs.writeText "${name}.c" src}
+    gcc -O -Wall -o $out $in
+    strip --strip-unneeded $out
+  '';
 }
diff --git a/krebs/5pkgs/nq.nix b/krebs/5pkgs/nq.nix
new file mode 100644
index 000000000..0f397a43c
--- /dev/null
+++ b/krebs/5pkgs/nq.nix
@@ -0,0 +1,16 @@
+{ fetchgit, stdenv }:
+
+stdenv.mkDerivation rec {
+  name = "nq-${rev}";
+  rev = "0eae839cb1";
+
+  src = fetchgit {
+    url = https://github.com/chneukirchen/nq;
+    inherit rev;
+    sha256 = "1150274750cde934932d65bd6053d7a0ba2404a59eadfb87fc6bd8a4fb70febb";
+  };
+
+  configurePhase = ''
+    sed -i "s:^PREFIX=.*:PREFIX=$out:" Makefile
+  '';
+}